【Excel VBA】全シートのスクロール位置、シート選択位置、セル選択位置を揃える

Option Explicit

' ::::::::::::::::::::::::::::::::::::::::::::::::::
' 全シートのスクロール位置を先頭にする
' ::::::::::::::::::::::::::::::::::::::::::::::::::
Public Sub ScrollTop()
    Dim sht As Worksheet
    Dim bVisible As Boolean
    
    ' 画面更新　無効
    Application.ScreenUpdating = False

    ' 全てのシートを処理する
    For Each sht In ActiveWorkbook.Worksheets
        ' シート表示状態を保管する
         bVisible = sht.Visible
        
        ' シートを表示する
        sht.Visible = xlSheetVisible
        
        ' シート選択
        sht.Select
        
        ' A1セル選択
        sht.Cells(1, 1).Select
        
        ' スクロール列の設定
        ActiveWindow.ScrollColumn = 1
        
        ' スクロール行の設定
        ActiveWindow.ScrollRow = 1
    
        ' シート表示状態を戻す
        sht.Visible = bVisible
    
    Next

    ' 一番左のシートを選択する
    Call SelectFirstSheet

    ' 画面更新　有効
    Application.ScreenUpdating = True

End Sub

' ::::::::::::::::::::::::::::::::::::::::::::::::::
' 一番左のシートを選択する
' ::::::::::::::::::::::::::::::::::::::::::::::::::
Private Sub SelectFirstSheet()
    Dim sht As Worksheet
    
   ' 全てのシートを処理する
    For Each sht In ActiveWorkbook.Worksheets
        ' シートが表示されているか判定する
        If sht.Visible = xlSheetVisible Then
            ' シートを選択しループを中断する
            sht.Select
            Exit Sub
        End If
    Next

End Sub